HMCL/HMCSM/build.gradle

/*
 * Hello Minecraft! Launcher.
 * Copyright (C) 2013  huangyuhui <huanghongxun2008@126.com>
 * 
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see {http://www.gnu.org/licenses/}.
 */

buildscript {
    repositories {
        mavenCentral();
        dependencies {
            classpath 'edu.sc.seis.gradle:launch4j:1.0.6'
            classpath 'me.tatarka:gradle-retrolambda:3.4.0'
        }
    }
}

plugins {
    id "edu.sc.seis.macAppBundle" version "2.1.6"
}

apply plugin: 'launch4j'
apply plugin: 'me.tatarka.retrolambda'

if (!hasProperty('mainClass')) {
    ext.mainClass = 'org.jackhuang.hellominecraft.svrmgr.Main'
}

def buildnumber = System.getenv("TRAVIS_BUILD_NUMBER")
if (buildnumber == null)
    buildnumber = System.getenv("BUILD_NUMBER")
if (buildnumber == null)
    buildnumber = "233"
    
def versionroot = System.getenv("VERSION_ROOT")
if (versionroot == null)
    versionroot = "0.8.7"

String mavenGroupId = 'HMCSM'
String mavenVersion = versionroot + '.' + buildnumber
String bundleName = "Hello Minecraft! Server Manager"

group = mavenGroupId
version = mavenVersion

String mavenArtifactId = name

task macAppCompressed(type: Zip, dependsOn: createApp) {
    archiveName "HMCSM-$mavenVersion-MacOSApp.zip"
    include '**'
    destinationDir file("$buildDir/libs/")
    from "$buildDir/macApp"
}

macAppBundle {
    mainClassName = mainClass
    icon = "src/main/icon.icns"
    javaProperties.put("apple.laf.useScreenMenuBar", "true")
}

configure(install.repositories.mavenInstaller) {
    pom.project {
        groupId = mavenGroupId
        artifactId = mavenArtifactId
        version = mavenVersion
    }
}

retrolambda {
    javaVersion = JavaVersion.VERSION_1_6
}

dependencies {
    compile project(":HMCLaF")
    compile project(":HMCUtils")
    compile ("org.jyaml:jyaml:1.3")
    compile ("org.tukaani:xz:1.5")
    compile ("org.jsoup:jsoup:1.7.2")
}

jar {
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    
    manifest {
        attributes 'Created-By'        : "Copyright(c) 2014 huangyuhui.",
                   'Main-Class'        : mainClass
    }
}

processResources {
    from(sourceSets.main.resources.srcDirs) {
        exclude 'icon.icns'
    }
}

build.dependsOn makeExecutable
build.dependsOn macAppCompressed